How To Send Emails From An Excel Spreadsheet Using VBA Scripts

How To Send Emails From An Excel Spreadsheet Using VBA Scripts:

Using emails as part of any program is a nice way to automate important tasks, and it also significantly improves the value and functionality of any program or script.

In the past, I’ve used email a whole lot in my batch jobs and other automated scripts, just like I’ve described in past articles here on using tools like Sendmail or Blat to issue emails straight from the command line, or from within a command line script.

These are great for those times when you have a script that’s monitoring the health of a computer or the status of a specific process, but what if you want to automate sending emails from within Office products like Word or Excel?

There are a lot of reasons why you might want to do so. Maybe you have staff that update documents or spreadsheets on a weekly basis, and you’d like to receive an email notification of when those updates take place, and even a report of the data from within those sheets. There are a few techniques you can use to program automated emails from within Excel, but my favorite remains CDO.

Sending Emails From Within Excel

You’re probably thinking that scripting outgoing email into an Excel VBA script is going to be painfully complicated. Well, that’s not the case at all.

CDO is a messaging component used in Windows for a few generations of the OS. It used to be called CDONTS, and then with the advent of Windows 2000 and XP, it was replaced with “CDO for Windows 2000″. This component is already included in your VBA installation within Word or Excel and it’s ready for use.

Using the component makes sending emails from within Windows products with VBA extremely easy. In this example, I’m going to use the CDO component in Excel to send out an email that will deliver the results from a specific Excel cell.

The first step is to go to the “Developer” menu tab, click on “Insert” in the Controls box, and then select a command button. Draw it into the sheet and then create a new macro for it.

When Excel opens up the VBA editor, you’re going to need to add the reference to the CDO library. You can access this in the Tools menu, and then scroll down the list until you find “Microsoft CDO for Windows 2000 Library“. Select the checkbox and click OK.

Now you’re ready to use CDO to issue emails from inside Excel. To do this, you first need ot create the mail objects and set up all of the fields that will be required for sending the email. Keep in mind that while many of the fields are optional, the From and To fields are required.

Dim CDO_Mail As Object
Dim CDO_Config As Object
Dim SMTP_Config As Variant
Dim strSubject as String
Dim strFrom as String
Dim strTo as String
Dim strCc as String
Dim strBcc as String
Dim strBody As String

strSubject = "Results from Excel Spreadsheet"
strFrom = "ryxxxxxx@xxxxxcast.net"
strTo = "rdxxxxxx@gmail.com"
strCc = ""
strBcc = ""
strBody = "The total results for this quarter are: " & Str(Sheet1.Cells(2, 1))

The cool thing about this is that you an build up any string you want to customize a full email message and assign it to the strBody variable. Piece together components of the message by using the “&” string to insert data from any of the Excel sheets right into the email message, just like I’ve shown above.

The next section of code is where you will configure CDO to use any external SMTP server that you want to use. In this case I don’t need to use SSL because my SMTP server doesn’t require it. CDO is capable of SSL, but that’s outside the scope of this article. If you need to use SSL, I highly recommend Paul Sadowski’s awesome writeup on using CDO.

Set CDO_Mail = CreateObject("CDO.Message")
On Error GoTo Error_Handling

Set CDO_Config = CreateObject("CDO.Configuration")
CDO_Config.Load -1

Set SMTP_Config = CDO_Config.Fields

With SMTP_Config
   .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.metrocast.net"
   .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
   .Update
End With

With CDO_Mail
   Set .Configuration = CDO_Config
End With

Now that you’ve configured the connection to the SMTP server for sending the email, all you have to do is fill in the appropriate fields for the CDO_Mail object, and issue the Send command. This is how you do that.

CDO_Mail.Subject = strSubject
CDO_Mail.From = strFrom
CDO_Mail.To = strTo
CDO_Mail.TextBody = strBody
CDO_Mail.CC = strCc
CDO_Mail.BCC = strBcc
CDO_Mail.Send

Error_Handling:
If Err.Description <> "" Then MsgBox Err.Description

So there you have it. There won’t be any pop-up boxes or security alert messages, which can happen when you resort to using the Outlook mail object. CDO simply puts together the email and utilizes your SMTP server connection details to fire off the message. It’s probably the easiest way I know to incorporate email into Word or Excel VBA scripts.

Here’s what the message looked like that I received in my inbox.

No hassle – just the data straight from within the Excel sheet delivered right to my email account. If you’re creative with how you put together the body string variable with all sorts of data from your Excel sheet, you can just imagine the cool automated email reports that you could put together. And if you don’t want to use a command button, just have the script run on the sheet or application close event.

Can you think up any cool uses for CDO in your own Excel, Access, or Word projects? Share your thoughts and ideas in the comments section below.

Shutterstock